[GROOVY-3428] Call site of static property is not updated after meta class is changed

• Type: Bug
• Status: Closed
• Priority: Major
• Resolution: Fixed
• Affects Version/s: 1.6
• Fix Version/s: 1.6.1, 1.7-beta-1
• Flags: Patch
• Assignee: Jochen Theodorou
• Reporter: Johnny Jian
• Created: 25/Mar/09 00:43
• Updated: 05/Apr/15 14:44
• Resolved: 06/Apr/09 17:35

Description

class StaticPropertyBug extends GroovyTestCase {

    MetaClassRegistry registry
    MetaClass originalMetaClass

    void setUp() {
        registry = GroovySystem.metaClassRegistry
        originalMetaClass = registry.getMetaClass(StaticPropertyFoo)
    }

    void tearDown() {
        registry.setMetaClass(StaticPropertyFoo, originalMetaClass)
    }

    void testCallSiteShouldBeUpdatedAfterProxyMetaClassIsSet() {
        def getFoo = { -> StaticPropertyFoo.bar }

        assert 'foo' == StaticPropertyFoo.bar
        assert 'foo' == getFoo()

        MetaClass mc = new StaticPropertyClassProxyMetaClass(registry, StaticPropertyFoo, originalMetaClass)
        registry.setMetaClass(StaticPropertyFoo, mc)

        assert 'static' == StaticPropertyFoo.bar
        assert 'static' == getFoo() // failed here
    }

    void testCallSiteShouldBeUpdatedAfterOriginalMetaClassIsRestored() {
        def getFoo = { -> StaticPropertyFoo.bar }

        MetaClass mc = new StaticPropertyClassProxyMetaClass(registry, StaticPropertyFoo, originalMetaClass)
        registry.setMetaClass(StaticPropertyFoo, mc)

        assert 'static' == StaticPropertyFoo.bar
        assert 'static' == getFoo()

        registry.setMetaClass(StaticPropertyFoo, originalMetaClass)

        assert 'foo' == StaticPropertyFoo.bar
        assert 'foo' == getFoo() // failed here
    }

}

class StaticPropertyFoo {
    static bar = 'foo'
}

class StaticPropertyClassProxyMetaClass extends ProxyMetaClass {
    StaticPropertyClassProxyMetaClass(MetaClassRegistry metaClassRegistry, Class aClass, MetaClass adaptee) {
        super(metaClassRegistry, aClass, adaptee)
    }
    public Object getProperty(Class aClass, Object object, String property, boolean b, boolean b1) {
        'static'
    }
}

A patch for this bug is included.